Anda belum log masuk.

MalayBasic

#1 2017-04-08 23:19:56

zomagic
Administrator
Dari: Kuala Lumpur
Didaftar: 2016-09-21
Post: 21

Clone Falppy bird

Aplikasi "Flappy",400,600,60,1,1
senarai kumpulan paip(x,y,scored)

highscore=BukaData("highscoredata") 

GpaipB = SediaGambar("paip_bawah.png")
Paksi GpaipB,lebar(GpaipB)/2,0 
GpaipA = SediaGambar("paip_atas.png")
Paksi GpaipA,lebar(GpaipA)/2,tinggi(GpaipA) 
Gburung = SediaGambar("burung.png",12) 
Paksi Gburung,lebar(Gburung)/2,tinggi(Gburung)/2 
Gground = SediaGambar("tanah.png")
Gbg = SediaGambar("latar.png",2) 
SediaFon("Arial",24) 

kelajuan = 2
burungx = 125 
burungy = 300 
UlangSemula = 30 
burungmy# = -4 
score=0
warnaburung = Rawak(3,0)
PosPaip = 100 
burungMati=0
frame = 0
bg = Rawak(2,1)
mode=1
time=Detik()

Fungsi Intro()
	frame = frame + kelajuan
	Gambar Gbg,0,0,bg 
	dari x = 1 Hingga 10 
		Gambar Gground,-50+(x*50)-(frame \ 50),500
	lagi
	Gambar Gburung,burungx,burungy+5*Sin(frame*3),1+(warnaburung*3)+(frame/16 \ 3)
	tulisOutline LebarSkrin()/2,100,Score
	tulisOutline LebarSkrin()/2,150,"Cloney Flappy!"
	tulisOutline LebarSkrin()/2,180,"Tekan tetikus untuk mula!"
	tulisOutline LebarSkrin()/2,210,"Jangan langgar paip!"
Tamat
Fungsi game()
	jika (Sentuhan()=1 atau kekunci(32)) dan bukan burungMati maka BuangSentuhan():burungmy = -4
	Gambar Gbg,0,0,bg 
	frame = frame + kelajuan 

	PosPaip = PosPaip - 1 
	
	jika PosPaip = 0 maka
		PosPaip = 90 
		paips@paip = cipta(paip) 
		paips.x = 500 
		paips.y = Rawak(400,150) 
		paips.scored = 0 
	dah
	untuk setiap paip
		paip.x = paip.x-kelajuan
		Gambar GpaipA,paip.x,paip.y-80
		Gambar GpaipB,paip.x,paip.y+80
		jika (Langgar(GpaipA,paip.x,paip.y-80,Gburung,burungx,burungy) atau Langgar(GpaipB,paip.x,paip.y+80,Gburung,burungx,burungy)) dan burungMati = 0
			burungMati = 1
			kelajuan = 0
			Warna 255,255,255 
			Kotak 0,0,LebarSkrin(),TinggiSkrin()
			time=Detik()
		dah
		jika paip.x < burungx dan paip.scored = 0 maka
			score = score + 1 
			paip.scored = 1
		dah
		jika paip.x < -50 maka buang paip
	lagi

	dari x = 1 Hingga 10 
		Gambar Gground,-50+(x*50)-(frame \ 50),500
	lagi
	
	Gambar Gburung,burungx,burungy+5*Sin(frame*3),1+(warnaburung*3)+(frame/16 \ 3)
	
	burungy = burungy + burungmy
	burungmy = burungmy+0.3 
	
	jika burungy > 490 dan burungmy > 0  maka
			jika burungMati = 0 maka
				Warna 255,255,255	
				Kotak 0,0,LebarSkrin(),TinggiSkrin()
				burungMati = 1
			dah
			burungy = 490
			kelajuan = 0
	dah
	
	jika burungMati = 0 maka
		tulisOutline LebarSkrin()/2,100,score
	lain
		UlangSemula = UlangSemula - 1 
		jika score > highscore maka
			SimpanData("highscoredata",score) 
			highscore = score
		dah
		tulisOutline LebarSkrin()/2,150,"Jumlah Mata: " + score
		tulisOutline LebarSkrin()/2,190,"Mata tertinggi: " + highscore
		tulisOutline LebarSkrin()/2,230,"Klik untuk semula"
	dah
	
	jika burungMati = 1 dan (Sentuh(0) atau kekunci(32)) dan Detik()-time>1000 dan UlangSemula < 0 maka
		
		untuk setiap paip
			buang paip
		lagi
		
		burungMati = 0
		score = 0 
		burungy = 200 
		kelajuan = 2 
		burungmy = -4 
		UlangSemula = 30 
		PosPaip = 100 
		warnaburung = Rawak(3,0) 
		bg = rawak(2,1) 
	dah
	
Tamat
Fungsi GelungUtama()
	semak mode
	kalau 1
		Intro()
		jika Sentuh(0) atau kekunci(32) maka mode=2
	kalau 2
		game()
	dahsemak
Tamat
Fungsi tulisOutline(textX,textY,textString$)
	Warna 0,0,0
	tulis textString,textX+1,textY,2
	tulis textString,textX-1,textY,2
	tulis textString,textX,textY+1,2
	tulis textString,textX,textY-1,2
	Warna 255,255,255
	tulis textString,textX,textY,2
Tamat

Ini adalah datanya..
data.zip
Dan ini pula skrinshotnya..
flappy.jpg


Offline

    Share Malaybasic on Facebook
   Home | Dokumen | Sembang | Hubungi

Board footer

Powered by FluxBB